Code

@echo off
rem Init
if "%~$PATH:0" == "" (set DUMMY=%0.bat) else (set DUMMY=%0)
for %%i in (%DUMMY%) do set ME_PATH=%%~dpi
for %%i in (%DUMMY%) do set ME_FILE=%%~nxi

rem Insure "DelayedExpansion"
set TEST_DELAY=X
if not "!TEST_DELAY!" == "X" (
    start /MIN /LOW "Sycronizing Buch.flat ..." CMD /V:ON /C%ME_PATH%%ME_FILE% %1 %2 %3 %4 %5 %6 %7 %8 %9
    goto EXIT_BATCH
)

if not exist buch.adr goto END

rem Main
if exist buch.flat del buch.flat>nul
for /f "delims=';' tokens=3,4" %%g in (buch.adr) do (
	set NUMBER=%%h
	set NUMBER_NEW=0

	for /l %%i in (0,1,30) do (
	    set CURR_CHAR=!NUMBER:~%%i,1!
	    for %%j in ("(",")","-"," ") do (
		    if "!CURR_CHAR!" == %%j set CURR_CHAR=
	    )

		set NUMBER_NEW=!NUMBER_NEW!!CURR_CHAR!
	)

	set NAME=%%g
	set NAME_NEW=

	for /l %%i in (0,1,50) do (
	    set CURR_CHAR=!NAME:~%%i,1!

	    if "!CURR_CHAR!" == " " (set CURR_CHAR=%%20) else (
	    if "!CURR_CHAR!" == ":" (set CURR_CHAR=%%3A) else (
	    if "!CURR_CHAR!" == "&" (set CURR_CHAR=%%26) else (
	    if "!CURR_CHAR!" == "ä" (set CURR_CHAR=%%A4) else (
	    if "!CURR_CHAR!" == "Ä" (set CURR_CHAR=%%84) else (
	    if "!CURR_CHAR!" == "ö" (set CURR_CHAR=%%B6) else (
	    if "!CURR_CHAR!" == "Ö" (set CURR_CHAR=%%96) else (
	    if "!CURR_CHAR!" == "ü" (set CURR_CHAR=%%BC) else (
	    if "!CURR_CHAR!" == "Ü" (set CURR_CHAR=%%9C) else (
	    if "!CURR_CHAR!" == "ß" (set CURR_CHAR=%%9F) else (
	    if "!CURR_CHAR!" == ";" (set CURR_CHAR=%%3B) else (
	    if "!CURR_CHAR!" == "(" (set CURR_CHAR=%%28) else (
	    if "!CURR_CHAR!" == ")" (set CURR_CHAR=%%29) else (
	    if "!CURR_CHAR!" == "<" (set CURR_CHAR=%%3C) else (
	    if "!CURR_CHAR!" == ">" (set CURR_CHAR=%%3E) else (
	    if "!CURR_CHAR!" == "[" (set CURR_CHAR=%%5B) else (

	    if "!CURR_CHAR!" == "]" (set CURR_CHAR=%%5D)
	    ))))))))))))))))

		set NAME_NEW=!NAME_NEW!!CURR_CHAR!
	)

	echo !NUMBER_NEW!;!NAME_NEW!>>buch.flat
)

:END
:EXIT_BATCH 

Code

@echo off
if "%1" == "" goto END
if "%1" == "0" (
	set OUTPUT=OHNE%%20RUFNUMMER
) else (
	set OUTPUT=%1
	for /f "delims=';' tokens=2" %%n in ('findstr /C:"%1" buch.flat') do (
		set OUTPUT=%%n
	)
)
echo %OUTPUT%>>N:\MACHINES\Server\Phoner\Incoming.log
start /B /MIN /ABOVENORMAL iexplore http://username:password@192.168.0.10:80/control/message?popup=Anruf%%3A%%20%OUTPUT%%%20%%28%2%%29
sleep 10
TASKKILL /F /FI "WINDOWTITLE eq http://192.168.0.10:80/control/message*" /IM iexplore.exe
:END 

Code

echo %OUTPUT%>>N:\MACHINES\Server\Phoner\Incoming.log 

Den Workshop führe ich heute erst einmal weiter, und zwar mit einer etwas verbesserten Version der vorstehenden Anrufer-Notizen:

---

Komfortablere Notizfunktion per Batch-Datei

Bei der Lösung, notepad.exe zu starten, um eine Notiz-Funktion für Anrufer zu bekommen, stören eigentlich drei Dinge:

a) Ruft ein Anrufer zum ersten Mal an, stört der Windows-Dialog, der nachfragt, ob notepad.exe geöffnet werden soll,

b) Das Phoner-Verzeichnis verkommt zum Notiz-Müll-Platz,

c) Dem Eintrag fehlen zuerst einmal Datum und Uhrzeit - wofür gibt es Computer, wenn man dass auch noch per Hand eintragen muss?

Abhilfe schafft eine Batch-Datei, die bei einem hereinkommenden Anruf gestartet wird. Aber jetzt erst einmal von Anfang an:

1. Schritt: 

In das Verzeichnis, in dem Phoner installiert wurde, muss ein neues Verzeichnis mit dem Namen Notizen angelegt werden, damit das folgende Script funktioniert.

2. Schritt

Mit dem Notepad wird eine Textdatei geöffnet, in die folgendes eingetragen wird:

Code

@ECHO OFF
SET DIR=Notizen
SET NOTIZ=%DIR%\%1 %2.txt
SET ANRUFER=%1
ECHO Neuer Anruf von %ANRUFER% >>"%NOTIZ%"
ECHO am %date:~0%, %time:~0,8% Uhr >>"%NOTIZ%"
ECHO.>>"%NOTIZ%"
ECHO.>>"%NOTIZ%"
START C:\WINDOWS\notepad.exe %NOTIZ%
SET NOTIZ=
SET ANRUFER=
SET DIR=
 

Achtung: Wenn das Verzeichnis Notizen, das vorher angelegt worden ist, anders heissen soll, dann ist der Verzeichnisname entprechend in der zweiten Code-Zeile anzupassen (hinter dem "="-Zeichen).

Diese TExt-Datei wird als ASCII-Text unter dem Namen phonerstart.bat (oder beliebig) in das Verzeichnis gespeichert, in dem auch die phoner.exe steht.

Schritt 3:

In Phoner, unter dem Menü Optionen|externe Applikation, wird die Datei phonerstart.bat und der Pfad zu ihr eingetragen.

Von jetzt an fragt Windows bei einem Anrufer, für den es noch keine Notiz gibt, nicht mehr nach, ob die Datei geöffnet werden soll,

Es öffnet sich ein notepad-fenster, welches Datum und Uhrzeit des Anrufes so wie die CallerID des Anrufers enthält,

und alle Notizen werden im Programm-Verzeichnis von Phoner im Ordner "Notizen" gespeichert.

Ein weiterer Vorteil - meiner Meinung nach - ist, dass man, ist man mal nicht am Platz, anhand der geöffneten Notepad-Fenster direkt sehen kann, welche Anrufe man verpasst hat. Will man nicht zurückrufen, so schliesst man diese Fenster einfach (und wird, wenn man nichts weiteres einträgt, nicht zum Speichern aufgefordert).

---

Dieses Script wurde unter Windows XP Pro, Windows XP Home und Windows Server 2003 getestet, und bringt dort die richtigen Resultate. Aufgrund der verwendeten %date- und %time-Variablen kann es u. U. sein, dass es unter anderen Versionen des Windows-OS nicht richtig funktioniert.

Viele Grüße vom Kai

Code

Die Syntax für den Dateinamen, Verzeichnisnamen oder die Datenträgerbezeichnung ist falsch.